AllowBypassKey-Eigenschaft

Access für Microsoft 365 Access 2021 Access 2019 Access 2016 Access 2013 Access 2010 Access 2007 Mehr... Weniger

Sie können die AllowBypassKey- Eigenschaft verwenden, um anzugeben, ob die UMSCHALTTASTE zum Umgehen der Starteigenschaften und des AutoExec-Makros aktiviert ist. Beispielsweise können Sie die AllowBypassKey- Eigenschaft auf False setzen, um zu verhindern, dass ein Benutzer die Starteigenschaften und das AutoExec-Makro umgeht.

Einstellung

Die AllowBypassKey- Eigenschaft verwendet die folgenden Einstellungen.

Einstellung	Beschreibung
Wahr	Aktivieren Sie die UMSCHALTTASTE, damit der Benutzer die Starteigenschaften und das AutoExec-Makro umgehen kann.
Falsch	Deaktivieren Sie die UMSCHALTTASTE, um zu verhindern, dass der Benutzer die Starteigenschaften und das AutoExec-Makro umgeht.

Sie können diese Eigenschaft mithilfe eines Makros oder VBA-Codes (Visual Basic for Applications) festlegen.

Um die AllowBypassKey- Eigenschaft mithilfe eines Makros oder VBA-Codes (Visual Basic for Applications) festzulegen, müssen Sie die Eigenschaft folgendermaßen erstellen:

• In einer Microsoft Access-Datenbank (.mdb oder .accdb) können Sie die Eigenschaft hinzufügen, indem Sie die CreateProperty- Methode verwenden und sie dann an die Properties -Auflistung des Database -Objekts anhängen.

• In einem Microsoft Access-Projekt (ADP) können Sie die Eigenschaft mithilfe der Add -Methode zur AccessObjectProperties- Auflistung des CurrentProject- Objekts hinzufügen.

Bemerkungen

Stellen Sie sicher, dass die AllowBypas sKey- Eigenschaft auf True gesetzt ist, wenn Sie eine Anwendung debuggen.

Die Einstellung der AllowBypassKey -Eigenschaft wird erst wirksam, wenn die Anwendungsdatenbank das nächste Mal geöffnet wird.

Beispiel

Das folgende Beispiel zeigt eine Prozedur namens SetBypassProperty, die den Namen der festzulegenden Eigenschaft, ihren Datentyp und die Einstellung übergibt. Die Allzweckprozedur ChangeProperty versucht, die AllowBypassKey- Eigenschaft festzulegen, und verwendet die CreateProperty- Methode, um die Eigenschaft an die Properties-Auflistung anzuhängen, wenn die Eigenschaft nicht gefunden wird. Dies ist erforderlich, da die AllowBypassKey- Eigenschaft erst nach dem Hinzufügen in der Properties -Auflistung angezeigt wird.

 Sub SetBypassProperty()
 Const DB_Boolean As Long = 1
 ChangeProperty "AllowBypassKey", DB_Boolean, False
 End Sub
 Function ChangeProperty(strPropName As String, _
 varPropType As Variant, _
 varPropValue As Variant) As Integer
 Dim dbs As Object, prp As Variant
 Const conPropNotFoundError = 3270
 Set dbs = CurrentDb
 On Error GoTo Change_Err
 dbs.Properties(strPropName) = varPropValue
 ChangeProperty = True
 Change_Bye:
 Exit Function
 Change_Err:
 If Err = conPropNotFoundError Then ' Property not found.
 Set prp = dbs.CreateProperty(strPropName, _
 varPropType, varPropValue)
 dbs.Properties.Append prp
 Resume Next
 Else
 ' Unknown error.
 ChangeProperty = False
 Resume Change_Bye
 End If
 End Function