PrtDevMode-Eigenschaft

Access für Microsoft 365 Access 2021 Access 2019 Access 2016 Access 2013 Access 2010 Access 2007 Mehr... Weniger

Gilt für

Formularobjekt
Berichtsobjekt

Sie können die PrtDevMode- Eigenschaft verwenden, um Informationen zum Druckgerätemodus festzulegen oder zurückzugeben, die für ein Formular oder einen Bericht im Dialogfeld „ Drucken " angegeben wurden. Lese-/ Schreibvariante .

Ausdruck . PrtDevMode

Ausdruck Erforderlich. Ein Ausdruck, der eines der Objekte in der Liste Gilt für zurückgibt.

Bemerkungen

Es wird dringend empfohlen, dass Sie das Win32 Software Development Kit konsultieren, um eine vollständige Dokumentation zu den Eigenschaften PrtDevMode , PrtDevNames und PrtMip zu erhalten.

Die PrtDevMode -Eigenschaftseinstellung ist eine 94-Byte-Struktur, die die im Win32 Software Development Kit definierte DEVMODE-Struktur widerspiegelt. Vollständige Informationen zu den PrtDevMode- Eigenschaftsmitgliedern finden Sie im Win32 Software Development Kit.

Die PrtDev Mode -Eigenschaft verwendet die folgenden Member.

Mitglied	Beschreibung
Gerätename	Eine Zeichenfolge mit maximal 32 Byte, die den Namen des Geräts angibt, das der Treiber unterstützt – beispielsweise „HP LaserJet IIISi", wenn der Hewlett-Packard LaserJet IIISi der angegebene Drucker ist. Jeder Druckertreiber hat eine eindeutige Zeichenfolge.
SpecVersion	Eine Ganzzahl, die die Versionsnummer der DEVMODE-Struktur im Win32 Software Development Kit angibt.
Treiberversion	Eine Ganzzahl , die die Versionsnummer des Druckertreibers angibt, die vom Entwickler des Druckertreibers zugewiesen wurde.
Größe	Eine Ganzzahl , die die Größe der DEVMODE-Struktur in Byte angibt. (Dieser Wert enthält nicht das optionale dmDriverData -Element für gerätespezifische Daten, die dieser Struktur folgen können.) Wenn eine Anwendung nur den treiberunabhängigen Teil der Daten bearbeitet, können Sie dieses Element verwenden, um dessen Länge herauszufinden ohne unterschiedliche Versionen berücksichtigen zu müssen.
TreiberExtra	Eine Ganzzahl , die die Größe des optionalen dmDriverData -Members für gerätespezifische Daten in Byte angibt, die dieser Struktur folgen können. Wenn eine Anwendung keine gerätespezifischen Informationen verwendet, setzen Sie dieses Mitglied auf 0.
Felder	Ein Long-Wert, der angibt, welche der verbleibenden Member in der DEVMODE-Struktur initialisiert wurden.
Orientierung	Eine Ganzzahl , die die Ausrichtung des Papiers angibt. Es kann entweder 1 (Hochformat) oder 2 (Querformat) sein.
Papier größe	Eine Ganzzahl , die die Größe des zu bedruckenden Papiers angibt. Wenn Sie dieses Element auf 0 oder 256 festlegen, werden die Länge und Breite des Papiers durch die Elemente PaperLength bzw. PaperWidth angegeben. Andernfalls können Sie das PaperSize-Mitglied auf einen vordefinierten Wert festlegen.
Papierlänge	Eine Ganzzahl , die die Papierlänge in Einheiten von 1/10 Millimeter angibt. Dieser Member überschreibt die vom PaperSize-Member angegebene Papierlänge für benutzerdefinierte Papierformate oder für Geräte wie Nadeldrucker, die auf einer Vielzahl von Papierformaten drucken können.
Papierbreite	Eine Ganzzahl , die die Papierbreite in Einheiten von 1/10 Millimeter angibt. Dieser Member überschreibt die vom PaperSize-Member angegebene Papierbreite.
Skala	Eine Ganzzahl , die den Faktor angibt, um den die Druckausgabe skaliert wird. Die scheinbare Seitengröße wird von der physischen Seitengröße um einen Skalierungsfaktor /100 skaliert. Beispielsweise würde ein Blatt Papier mit den Maßen 8,5 x 11 Zoll (Letter-Format) mit einem Skalierungswert von 50 so viele Daten enthalten wie eine Seite mit den Maßen 17 x 22 Zoll, da der ausgegebene Text und die Grafiken die Hälfte ihrer ursprünglichen Höhe und Breite aufweisen würden .
Kopien	Eine Ganzzahl , die die Anzahl der gedruckten Kopien angibt, wenn das Druckgerät mehrseitige Kopien unterstützt.
Standardquelle	Eine Ganzzahl , die das Standardfach angibt, aus dem das Papier eingezogen wird.
Druckqualität	Eine Ganzzahl , die die Druckerauflösung angibt. Die Werte sind –4 (hoch), –3 (mittel), –2 (niedrig) und –1 (Entwurf).
Farbe	Eine Ganzzahl . Gibt bei einem Farbdrucker an, ob die Ausgabe in Farbe gedruckt wird. Die Werte sind 1 (Farbe) und 2 (Monochrom).
Duplex	Eine Ganzzahl . Gibt bei einem Drucker mit Duplexdruck an, ob die Ausgabe auf beiden Seiten des Papiers gedruckt wird. Die Werte sind 1 (einfach), 2 (horizontal) und 3 (vertikal).
YAuflösung	Eine Ganzzahl , die die y-Auflösung des Druckers in Punkten pro Zoll (dpi) angibt. Wenn der Drucker dieses Mitglied initialisiert, gibt das PrintQuality-Mitglied die x-Auflösung des Druckers in dpi an.
TTOption	Eine Ganzzahl , die angibt, wie TrueType-Schriftarten gedruckt werden.
Sortieren	Eine Ganzzahl , die angibt, ob beim Drucken mehrerer Exemplare eine Sortierung verwendet werden soll. Die Verwendung unsortierter Kopien ermöglicht eine schnellere und effizientere Ausgabe, da die Daten nur einmal an den Drucker gesendet werden.
Formularname	Eine Zeichenfolge mit maximal 16 Zeichen, die das zu verwendende Papierformat angibt; B. „Letter" oder „Legal".
Pad	Ein Long- Wert, der zum Auffüllen von Leerzeichen, Zeichen oder Werten für zukünftige Versionen verwendet wird.
Bits	Ein Long- Wert, der die Farbauflösung des Anzeigegeräts in Bit pro Pixel angibt.
PW	Ein Long- Wert, der die Breite der sichtbaren Geräteoberfläche (Bildschirm oder Drucker) in Pixel angibt.
PH	Ein Long- Wert, der die Höhe der sichtbaren Geräteoberfläche (Bildschirm oder Drucker) in Pixel angibt.
DFI	Ein Long- Wert, der den Anzeigemodus des Geräts angibt.
DFR	Ein Long- Wert, der die Frequenz des Anzeigegeräts in einem bestimmten Modus in Hertz (Zyklen pro Sekunde) angibt.

Hinweis: Sie können die PrtDevMode- Eigenschaft mit Visual Basic for Applications (VBA)-Code festlegen.

Diese Eigenschaftseinstellung ist in der Entwurfs- oder Layoutansicht schreib-/lesbar und in anderen Ansichten schreibgeschützt.

Druckertreiber können gerätespezifische Daten unmittelbar nach den 94 Bytes der DEVMODE-Struktur hinzufügen. Aus diesem Grund ist es wichtig, dass die oben skizzierten DEVMODE-Daten 94 Byte nicht überschreiten.

Nur Druckertreiber, die die ExtDeviceMode- Funktion exportieren, verwenden die DEVMODE-Struktur.

Eine Anwendung kann die von einem Drucker unterstützten Papiergrößen und -namen abrufen, indem sie die Werte DC_PAPERS, DC_PAPERSIZE und DC_PAPERNAMES zum Aufrufen der DeviceCapabilities- Funktion verwendet.

Vor dem Festlegen des Werts des TTOption-Mitglieds sollten Anwendungen herausfinden, wie ein Druckertreiber TrueType-Schriftarten verwenden kann, indem sie den DC_TRUETYPE-Wert verwenden, um die DeviceCapabilities- Funktion aufzurufen.

Beispiel

Das folgende Beispiel verwendet die PrtDevMode -Eigenschaft, um die benutzerdefinierte Seitengröße für einen Bericht zu überprüfen:

 Private Type str_DEVMODE
 RGB As String * 94
 End Type
 Private Type type_DEVMODE
 strDeviceName As String * 32
 intSpecVersion As Integer
 intDriverVersion As Integer
 intSize As Integer
 intDriverExtra As Integer
 lngFields As Long
 intOrientation As Integer
 intPaperSize As Integer
 intPaperLength As Integer
 intPaperWidth As Integer
 intScale As Integer
 intCopies As Integer
 intDefaultSource As Integer
 intPrintQuality As Integer
 intColor As Integer
 intDuplex As Integer
 intResolution As Integer
 intTTOption As Integer
 intCollate As Integer
 strFormName As String * 32
 lngPad As Long
 lngBits As Long
 lngPW As Long
 lngPH As Long
 lngDFI As Long
 lngDFr As Long
 End Type
 Public Sub CheckCustomPage(ByVal rptName As String)
 Dim DevString As str_DEVMODE
 Dim DM As type_DEVMODE
 Dim strDevModeExtra As String
 Dim rpt As Report
 Dim intResponse As Integer
 ' Opens report in Design view.
 DoCmd.OpenReport rptName, acDesign
 Set rpt = Reports(rptName)
 If Not IsNull(rpt.PrtDevMode) Then
 strDevModeExtra = rpt.PrtDevMode
 ' Gets current DEVMODE structure.
 DevString.RGB = strDevModeExtra
 LSet DM = DevString
 If DM.intPaperSize = 256 Then
 ' Display user-defined size.
 intResponse = MsgBox("The current custom page size is " & _
 DM.intPaperWidth / 254 & " inches wide by " & _
 DM.intPaperLength / 254 & " inches long. Do you want " & _
 "to change the settings?", vbYesNo + vbQuestion)
 Else
 ' Currently not user-defined.
 intResponse = MsgBox("The report does not have a custom page size. " & _
 "Do you want to define one?", vbYesNo + vbQuestion)
 End If
 If intResponse = vbYes Then
 ' User wants to change settings. Initialize fields.
 DM.lngFields = DM.lngFields Or DM.intPaperSize Or _
 DM.intPaperLength Or DM.intPaperWidth
 ' Set custom page.
 DM.intPaperSize = 256
 ' Prompt for length and width.
 DM.intPaperLength = InputBox("Please enter page length in inches.") * 254
 DM.intPaperWidth = InputBox("Please enter page width in inches.") * 254
 ' Update property.
 LSet DevString = DM
 Mid(strDevModeExtra, 1, 94) = DevString.RGB
 rpt.PrtDevMode = strDevModeExtra
 End If
 End If
 Set rpt = Nothing
 End Sub

Das folgende Beispiel zeigt, wie die Ausrichtung des Berichts geändert wird. In diesem Beispiel wird die Ausrichtung je nach aktueller Ausrichtung des Berichts vom Hochformat ins Querformat oder vom Querformat ins Hochformat geändert.

 Public Sub SwitchOrient(ByVal strName As String)
 Const DM_PORTRAIT = 1
 Const DM_LANDSCAPE = 2
 Dim DevString As str_DEVMODE
 Dim DM As type_DEVMODE
 Dim strDevModeExtra As String
 Dim rpt As Report
 ' Opens report in Design view.
 DoCmd.OpenReport strName, acDesign
 Set rpt = Reports(strName)
 If Not IsNull(rpt.PrtDevMode) Then
 strDevModeExtra = rpt.PrtDevMode
 DevString.RGB = strDevModeExtra
 LSet DM = DevString
 DM.lngFields = DM.lngFields Or DM.intOrientation
 ' Initialize fields.
 If DM.intOrientation = DM_PORTRAIT Then
 DM.intOrientation = DM_LANDSCAPE
 Else
 DM.intOrientation = DM_PORTRAIT
 End If
 ' Update property.
 LSet DevString = DM
 Mid(strDevModeExtra, 1, 94) = DevString.RGB
 rpt.PrtDevMode = strDevModeExtra
 End If
 Set rpt = Nothing
 End Sub